Tetrahedron

A tetrahedron is a pyramid with a triangular-base. It has 4 vertices, 6 edges, and 4 triangular faces. Here is an example:

Graphics3D[Tetrahedron[],Boxed->False]

Another Polyhedron

The following polyhedron has two tetrahedralizations.

verts2={{1,0,0},{-(1/2),((Sqrt[3])/2),0},{-(1/2),-((Sqrt[3])/2),0},{0,0,1},{0,0,-1}};
faces2={{1,2,4},{1,3,4},{2,3,4},{1,2,5},{1,3,5},{2,3,5}};
Graphics3D[{Opacity[0.8],Polyhedron[verts2,faces2]},Boxed->False]

Here is one tetrahedralization of this polyhedron.

(* upper tetrahedron *)
verts3a=Drop[verts2,-1];
faces3={{1,2,4},{1,3,4},{2,3,4},{1,2,3}};
(* lower tetrahedron *)
verts3b=({0,0,-0.3}+#&) /@ Drop[verts2,{4}];
(* draw the picture *)
Graphics3D[{Opacity[0.8],Polyhedron[verts3a,faces3],Polyhedron[verts3b,faces3]},Boxed->False]

Here is another tetrahedralization of this polyhedron.

(* left tetrahedron *)
verts3c=Drop[verts2,{2}];
(* right tetrahedron *)
verts3d=({0,0.3,0}+#&) /@ Drop[verts2,{3}];
(* back tetrahedron *)
verts3e=({-0.26,0.15,0}+#&) /@ Drop[verts2,1];
(* draw the picture *)
Graphics3D[{Opacity[0.8],Polyhedron[verts3c,faces3],Polyhedron[verts3d,faces3],Polyhedron[verts3e,faces3]},Boxed->False]

Schönhardt Polyhedron

The Schönhardt polyhedron has no tetrahedralization.

verts4={{1,0,0},{-(1/2),((Sqrt[3])/2),0},{-(1/2),-((Sqrt[3])/2),0},{((Sqrt[3])/2),(1/2),1},{-((Sqrt[3])/2),(1/2),1},{0,-1,1}};
faces4={{1,2,3},{4,5,6},{1,2,5},{1,4,5},{2,3,6},{2,5,6},{3,1,4},{3,6,4}};
Show[Graphics3D[{Opacity[0.8],Polyhedron[verts4,faces4]}],Boxed->False,ViewPoint->{10,0,.5}]

Here is the view from above:

Show[Graphics3D[{Opacity[0.8],Polyhedron[verts4,faces4]}],Boxed->False,ViewPoint->{0,0,10}]